{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs";
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    sls-steam = {
      url = "github:AceSLS/SLSsteam/a1b30e8183651a6d3a016365b18d8893964af7cc";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    gsr-ui = {
      url = "github:rPlakama/gsr-ui-nix/c1ac4ac2fd962b7c985edb1e420bdc5b3dce56f6";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    zen-browser.url = "github:0xc000022070/zen-browser-flake";
    xremap-flake.url = "github:xremap/nix-flake";
    yazi.url = "github:sxyazi/yazi";
    millennium.url = "github:SteamClientHomebrew/Millennium?dir=packages/nix";
    bcdl-free = {
      url = "git+https://git.pizzasucht.net/KeksNino/free-bandcamp-downloader";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixvim.url = "github:nix-community/nixvim";
    hyprsplit.url = "github:shezdy/hyprsplit";
    nix-flatpak.url = "github:gmodena/nix-flatpak/?ref=latest";
    nixpkgs-patcher.url = "github:gepbird/nixpkgs-patcher";
    nixpkgs-patch-xdg-desktop-portal = {
      url = "https://github.com/NixOS/nixpkgs/pull/548762.diff";
      flake = false;
    };
  };

  outputs =
    {
      nixpkgs,
      home-manager,
      zen-browser,
      xremap-flake,
      sls-steam,
      yazi,
      millennium,
      gsr-ui,
      bcdl-free,
      nixvim,
      hyprsplit,
      nix-flatpak,
      nixpkgs-patcher,
      ...
    }@inputs:
    let
      system = "x86_64-linux";
    in
    {
      nixosConfigurations.nixos-desktop = nixpkgs-patcher.lib.nixosSystem {
        specialArgs = {
          inherit system;
          inherit (inputs)
            sls-steam
            bcdl-free
            xremap-flake
            nixvim
            nix-flatpak
            ;
        };
        nixpkgsPatcher.inputs = inputs;
        modules = [
          ./hosts/desktop/configuration.nix
          ./hosts/desktop/hardware-configuration.nix
          ./modules/common.nix
          ./modules/desktop/xremap.nix
          ./modules/desktop/flatpak.nix
          home-manager.nixosModules.home-manager
          gsr-ui.nixosModules.default
          {
            nixpkgs.overlays = [
              millennium.overlays.default
              yazi.overlays.default
            ];

            home-manager.users.user = import ./hosts/desktop/home-manager/home.nix;

            home-manager.extraSpecialArgs = {
              inherit zen-browser hyprsplit;
            };

            programs.gpu-screen-recorder = {
              package = gsr-ui.packages.${system}.gpu-screen-recorder;
              enable = true;
              ui.enable = true;
            };
          }
        ];
      };
      nixosConfigurations.music-server = nixpkgs.lib.nixosSystem {
        specialArgs = {
          inherit
            inputs
            bcdl-free
            system
            ;
        };
        modules = [
          ./hosts/music-server/configuration.nix
          ./hosts/music-server/hardware-configuration.nix
          ./modules/common.nix
          home-manager.nixosModules.home-manager
          {
            home-manager.users.user = import ./hosts/music-server/home-manager/home.nix;
          }
        ];
      };
    };
}